The Image::ExifTool Perl Library Module
Description
The Image::ExifTool library provides a set of Perl modules to read and
write meta information in a wide variety of image, audio, video and document
files.
All ExifTool features are accessed through the methods of the public
interface listed below. Other Image::ExifTool methods and modules should not be
accessed directly because their interface may change with future versions.
The ExifTool methods should never die or issue a warning to STDERR if called
with the proper arguments (with the exception of
SetNewValue which may send an error message to
STDERR, but only when called in scalar context). Error and warning messages
that occur during processing are stored in the values of the Error and Warning
tags, and are accessible via the GetValue method to
retrieve a single Error or Warning message, or GetInfo to
retrieve any number of them.
The ExifTool methods are not thread safe.
The ExifTool module may be used by simply calling the
ImageInfo function:
use Image::ExifTool qw(:Public);
my $info = ImageInfo('image.jpg');
|
or in a more object-oriented fashion, by creating an ExifTool object:
use Image::ExifTool;
my $exifTool = new Image::ExifTool;
my $info = $exifTool->ImageInfo('image.jpg');
|
The object-oriented method allows more flexibility, but is slightly more
complicated. You choose the method that you prefer.
The $info value returned by ImageInfo in the above
examples is a reference to a hash containing the tag/value pairs. Here is a
simplified example which prints out this information:
foreach (keys %$info) {
print "$_ => $$info{$_}\n";
}
|
See ImageInfo for a more detailed description of the
info hash entries.
And the technique for writing meta information is equally simple:
use Image::ExifTool;
my $exifTool = new Image::ExifTool;
$exifTool->SetNewValue(Author => 'Phil Harvey');
$exifTool->WriteInfo('image.jpg','modified_image.jpg');
|
User-defined tags can be added via the ExifTool configuration file, or by
defining the %Image::ExifTool::UserDefined hash before calling any ExifTool
functions. See "ExifTool_config" in the ExifTool
distribution for more details.
By default ExifTool looks for a configuration file named ".ExifTool_config"
first in your home directory, then in the directory of the application script,
but a different directory may be specified by setting the EXIFTOOL_HOME
environment variable, or a different file may be specified by setting the
ExifTool "configFile" variable before using Image::ExifTool. For
example:
BEGIN { $Image::ExifTool::configFile = '/Users/phil/myconfig.cfg' }
use Image::ExifTool;
|
The configuration feature may also be disabled by setting
"configFile" to an empty string:
BEGIN { $Image::ExifTool::configFile = '' }
use Image::ExifTool;
|
Read image file and return meta information. This is the one-step function for
retrieving meta information from an image. Internally,
ImageInfo calls ExtractInfo
to extract data from the image, GetInfo to generate the
information hash, and GetTagList for the returned tag
list.
| Prototype | ImageInfo($;@) |
| Inputs | 0) [optional] ExifTool object reference
1) File name, file reference or scalar reference
2-N) [optional] list of tag names to find (or tag list reference or
options reference, see below)
|
| Returns | Reference to hash of tag key/value pairs |
Examples:
Non object-oriented example showing use of options and returning tag list:
use Image::ExifTool qw(ImageInfo);
my @ioTagList;
my $info;
$info = ImageInfo('image.jpg', \@ioTagList, {Sort => 'Group0'});
|
Object-oriented example to read from a file that is already open:
my $exifTool = new Image::ExifTool;
$info = $exifTool->ImageInfo(\*FILE_PT, 'Aperture', 'ShutterSpeed', 'ISO');
|
Extract information from an image in memory:
$info = $exifTool->ImageInfo(\$imageData);
|
Extract information from an embedded thumbnail image:
$info = ImageInfo('image.jpg', 'thumbnailimage');
my $thumbInfo = ImageInfo($$info{ThumbnailImage});
|
Using an ExifTool object to set the options before calling
ImageInfo:
my $filename = shift || die "Please specify filename\n";
my @ioTagList = qw(filename imagesize xmp:creator exif:* -ifd1:*);
$exifTool->Options(Unknown => 1, DateFormat => '%H:%M:%S %a. %b. %e, %Y');
$info = $exifTool->ImageInfo($filename, \@ioTagList);
|
Function Arguments:
ImageInfo is very flexible about the arguments
passed to it, and interprets them based on their type. It may be called with
one or more arguments. The one required argument is either a SCALAR (the image
file name), a file reference (a reference to the image file) or a SCALAR
reference (a reference to the image in memory). Other arguments are optional.
The order of the arguments is not significant, except that the first SCALAR is
taken to be the file name unless a file reference or scalar reference comes
earlier in the argument list.
Below is a more detailed explanation of how the ImageInfo
function arguments are interpreted.
| ExifTool ref |
ImageInfo may be called with an ExifTool object if
desired. Advantages of using the object-oriented form are that options may be
set before calling ImageInfo, and the object may be
used afterward to access member functions. Must be the first argument if used.
|
| SCALAR |
The first scalar argument is taken to be the file name unless an earlier
argument specified the image data via a file reference (file ref) or data
reference (SCALAR ref). The remaining scalar arguments are names of tags for
requested information. All tags are returned if no tags are specified.
Tag names are case-insensitive and may be prefixed by optional group names
separated by colons. A group name may begin with a family number (eg.
'1IPTC:Keywords'), to restrict matches to a specific family. In the
tag name, a '?' matches any single character and a '*'
matches zero or more characters. Thus 'GROUP:*' represents all
tags in a specific group. Wildcards may not be used in group names, with the
exception that a group name of '*' may be used to extract all
available instances of a tag regardless of the
Duplicates setting (eg. '*:WhiteBalance').
Multiple groups may be specified (eg. 'EXIF:Time:*' extracts all
EXIF Time tags). And finally, a leading '-' indicates a tag to be
excluded (eg. '-IFD1:*'), or a trailing '#' causes the
ValueConv value to be returned for this tag.
Note that keys in the returned information hash and elements of the returned tag
list are not necessarily the same as these tag names because group names are
removed, the case may be changed, and an instance number may be added. For this
reason it is best to use either the keys of the returned hash or the elements of
the returned tag list when accessing the tag values.
See the TagNames documentation for a
complete list of ExifTool tag names.
|
| File ref |
A reference to an open image file. If you use this method (or a SCALAR
reference) to access information in an image, the FileName and Directory tags
will not be returned. (Also, the FileSize, FileModifyDate, FilePermissions and
FileAttributes tags will not be returned unless it is a plain file.) Image
processing begins at the current file position, and on return the file position
is unspecified. May be either a standard filehandle or a reference to a
File::RandomAccess object.
[Advanced: To allow a non-rewindable stream (eg. a network socket) to be
re-read after processing with ExifTool, first wrap the file reference in a
File::RandomAccess object, then pass this object to
ImageInfo. The File::RandomAccess object will buffer
the file if necessary, and may be used to re-read the file after
ImageInfo returns.]
|
| SCALAR ref |
A reference to image data in memory.
|
| ARRAY ref |
Reference to a list of tag names. On entry, any elements in the list are added
to the list of requested tags. On return, this list is updated to contain an
ordered list of tag keys for the returned information.
There will be 1:1 correspondence between the requested tags and the returned
tag keys only if the Duplicates option is 0 and
Sort is 'Input'. (With
Duplicates enabled, there may be more entries in the
returned list of tag keys, and with other Sort settings the
entries may not be in the same order as requested.) If a requested tag doesn't
exist, a tag key is still generated, but the tag value is undefined.
|
| HASH ref |
Reference to a hash containing the options settings. See
Options documentation below for a list of available
options. Options specified as arguments to ImageInfo
take precedence over Options settings.
|
Return Value:
ImageInfo returns a reference to a hash of tag
key/value pairs. The tag keys are identifiers, which are similar to the tag
names but may have an appended instance number if multiple tags with the same
name were extracted from the image. Many of the ExifTool functions require a
tag key as an argument. Use GetTagName to get the tag
name for a given tag key. Note that the case of the tag names may not be the
same as requested.
Values of the returned hash are usually simple scalars, but a scalar
reference is used to indicate binary data and an array reference may be used to
indicate a list. Also, a hash reference may be returned if the
Struct option is used. Lists of values are joined by
commas into a single string only if the PrintConv option is enabled and the List
option is disabled (which are the defaults). Note that binary values are not
necessarily extracted unless specifically requested, or the Binary option is
enabled and the tag is not specifically excluded. If not extracted the value is
a reference to a string of the form "Binary data ##### bytes".
Here is a simple example to print out the information returned by
ImageInfo:
foreach (keys %$info) {
my $val = $$info{$_};
if (ref $val eq 'ARRAY') {
$val = join(', ', @$val);
} elsif (ref $val eq 'SCALAR') {
$val = '(Binary data)';
}
printf("%-24s : %s\n", $_, $val);
}
|
which gives output like this (PrintConv enabled):
WhiteBalance : Auto
FNumber : 3.5
InteroperabilityOffset : 936
XResolution : 72
ISO : 100
ThumbnailImage : (Binary data)
FlashOn : On
Make : FUJIFILM
ShutterSpeedValue : 1/64
ExposureCompensation : 0
Sharpness : Soft
ResolutionUnit : inches
|
Notes:
ExifTool returns all values as byte strings of encoded characters. Perl wide
characters are not used. See FAQ number 10 for
details about the encodings. By default, most returned strings are encoded in
UTF-8. For these, Encode::decode_utf8() may be used to convert to a sequence of
logical Perl characters.
As well as tags representing information extracted from the image, the
following Extra tags generated by ExifTool may
be returned:
| ExifToolVersion | The ExifTool version number |
| Error | An error message if the image could not be processed |
| Warning | A warning message if problems were encountered
while processing the image |
Create a new ExifTool object.
Example:
my $exifTool = new Image::ExifTool;
|
Note that ExifTool uses AUTOLOAD to load non-member methods, so any class
using Image::ExifTool as a base class must define an AUTOLOAD which calls
Image::ExifTool::DoAutoLoad(). ie)
sub AUTOLOAD
{
Image::ExifTool::DoAutoLoad($AUTOLOAD, @_);
}
|
|
The following functions require an ExifTool object as the first argument
|
Get/set ExifTool options. This function can be called to set the default
options for an ExifTool object. Options set this way are in effect for
all function calls but may be overridden by options passed as arguments
to some functions. Option names are not case sensitive.
The default option values may be changed by defining a
%Image::ExifTool::UserDefined::Options hash. See the
ExifTool_config file in the full ExifTool
distribution for examples.
| Prototype | Options($$;@) |
| Inputs | 0) ExifTool object reference
1) Parameter name (case-insensitive, see table below)
2) [optional] Option value if specified (may be undef to clear option)
3-N) [optional] Additional parameter/value pairs
|
| Returns | Previous value of last specified parameter |
Available options:
| ExifTool Options |
|---|
| Option | Description | Values | Default |
|---|
| Binary | Flag to extract the value data for all binary tags.
Tag values representing large binary data blocks (eg. ThumbnailImage)
are not necessarily extracted unless this option is set or the tag is
specifically requested by name. |
0 or 1 | undef |
| ByteOrder | The byte order for newly created EXIF segments when
writing. Note that if EXIF information already exists, the existing order is
maintained. If ByteOrder is not defined, then the order of the maker notes is
used (if they are being copied), otherwise big-endian ('MM') order is assumed.
This can also be set via the ExifByteOrder tag,
but the ByteOrder option takes precedence if both are set. |
'MM','II' or undef | undef |
| Charset | Character set for encoding character
strings passed to/from ExifTool containing code points above U+007F. Note
that this option affects some types of information when reading/writing the
file and other types when getting/setting tag values, so it must be defined
for both types of access. Charset values listed to the right have aliases
which are given in brackets. Case is not significant. See
FAQ #10 for more information about character sets. |
| UTF8 | (cp65001, UTF-8) |
| Latin | (cp1252, Latin1) |
| Latin2 | (cp1250) |
| Cyrillic | (cp1251, Russian) |
| Greek | (cp1253) |
| Turkish | (cp1254) |
| Hebrew | (cp1255) |
| Arabic | (cp1256) |
| Baltic | (cp1257) |
| Vietnam | (cp1258) |
| Thai | (cp874) |
| MacRoman | (cp10000, Mac, Roman) |
| MacLatin2 | (cp10029) |
| MacCyrillic | (cp10007) |
| MacGreek | (cp10006) |
| MacTurkish | (cp10081) |
| MacRomanian | (cp10010) |
| MacIceland | (cp10079) |
| MacCroatian | (cp10082) |
| 'UTF8' |
| CharsetEXIF | Internal encoding to use for stored
EXIF "ASCII" string values. May also be set to undef to pass through EXIF
"ASCII" values without recoding. Set to "UTF8" to conform with the MWG
recommendation. |
(see Charset option)
or undef | undef |
| CharsetFileName | External character set
used when specifying file names. When set in Windows, this triggers use of
Windows Unicode file library routines (requires Win32API::File). |
(see Charset option)
or undef | undef |
| CharsetID3 | Internal encoding to assume for ID3v1 strings. By
the specification ID3v1 strings should be encoded in ISO 8859-1 (essentially
'Latin'), but some applications may use local encoding instead. This option
allows different encodings to be specified. |
(see Charset option) | 'Latin' |
| CharsetIPTC | Fallback internal IPTC character set to assume if IPTC information
contains no CodedCharacterSet tag. |
(see Charset option) | 'Latin' |
| CharsetPhotoshop | Internal encoding to assume for Photoshop IRB resource names. |
(see Charset option) | 'Latin' |
| CharsetQuickTime | Internal encoding to assume for QuickTime
strings stored with an unspecified encoding. |
(see Charset option) | 'MacRoman' |
| Compact | Flag to write compact output. The XMP specification suggests
that the data be padded with blanks to allow in-place editing. With this
flag set the 2kB of padding is not written. Note that this only effects
embedded XMP since padding is never written for stand-alone XMP files. |
0 or 1 | undef |
| Composite | Flag to generate Composite tags when extracting information. |
0 or 1 | 1 |
| Compress | Flag to write new values in compressed format if possible.
Has no effect unless Compress::Zlib is installed. |
0 or 1 | undef |
| CoordFormat | Specify output format for GPS coordinates. |
A printf-style format string with specifiers for degrees, minutes and
seconds in that order, however minutes and seconds may be omitted. If the
hemisphere is known, a reference direction (N, S, E or W) is appended to
each printed coordinate, but adding a '+' to the first format
specifier (eg. '%+.6f') prints a signed coordinate instead.
The default for reading is equivalent to a format string of
q{%d deg %d' %.2f"}, but to avoid a loss
of precision the default for copying tags with
SetNewValuesFromFile is
q{%d %d %.8f}.
| undef |
| DateFormat | Output format for date/time values. If date can not
be converted, value is left unchanged unless the StrictDate option is set.
Timezones are ignored. | See strftime manpage for details. The default
is similar to a format string of "%Y:%m:%d %H:%M:%S". |
undef |
| Duplicates | Flag to return values from
tags with duplicate names when extracting information. |
0 or 1 | 1 |
| Escape |
Escape special characters in extracted values for
HTML or XML. Also unescapes HTML or XML character entities in input values
passed to SetNewValue. | HTML, XML or undef |
undef |
| Exclude |
Exclude specified tags when extracting information. |
Tag name or reference to a list of tag names to
exclude. Case is not significant. Tags may also be excluded by preceding
their name with a '-' in the arguments to ImageInfo. |
undef |
| ExtendedXMP | This setting affects the
reading and editing of extended XMP in JPEG images. According to the XMP
specification, extended XMP is only valid if it has the GUID specified by
the HasExtendedXMP tag. ExifTool
9.95 and earlier would read extended XMP regardless of GUID, but with the
addition of this option in version 9.96 the default behaviour was changed to
conform with the XMP specification (to read only extended XMP with the
proper GUID). This option should be set to 2 to emulate pre-9.96 behaviour
and read all extended XMP. It may also be set to a GUID to read a specific
extended XMP, or 0 to ignore extended XMP entirely. |
| 0 = | ignore extended XMP |
| 1 = | valid GUID only |
| 2 = | any GUID |
| guid = | specific GUID |
| 1 |
| ExtractEmbedded |
Flag to extract information from embedded
documents in EPS files, embedded EPS information and JPEG and Jpeg2000
images in PDF files, embedded MPF images in JPEG and MPO files, streaming
metadata in AVCHD videos, and the resource fork of Mac OS files. |
0 or 1 | undef |
| FastScan |
Flag to increase speed of extracting information
from JPEG images. With this option set to 1, ExifTool will not scan to the
end of a JPEG image to check for an AFCP, CanonVRD, FotoStation,
PhotoMechanic, MIE or PreviewImage trailer. This also stops the parsing
after the first comment in GIF images, and at the audio/video data with
RIFF-format files (AVI, WAV, etc), so any trailing metadata (ie.eg. XMP written
by some utilities) may be missed. When combined with the ScanForXMP option,
prevents scanning for XMP in recognized file types. With a value of 2,
ExifTool will also avoid extracting any EXIF MakerNote information. When set
to 3, the file is not actually parsed, and only an initial guess at FileType
and some pseudo tags are returned. |
0, 1, 2 or 3 | undef |
| Filter |
Perl expression used to filter all returned tag values. Applies to
PrintConv values only. | Expression to act on the
value of the Perl default variable ($_), changing the value of this variable
as required | undef |
| FixBase |
Fix maker notes base offset. Allows values to be extracted from maker notes
which have been corrupted by editing with 3rd party software. |
An integer specifying a value to be added to the
maker notes base offset, or the empty string ('') for ExifTool to take its
best guess at the correct base. |
undef |
| GeoMaxIntSecs |
Maximum interpolation time in seconds for
geotagging. Geotagging is treated as an extrapolation if the Geotime value
lies between two fixes in the same track which are separated by a number of
seconds greater than this. Otherwise, the coordinates are calculated as a
linear interpolation between the nearest fixes on either side of the Geotime
value. Set to 0 to disable interpolation and use the coordinates of the
nearest fix instead (provided it is within GeoMaxExtSecs, otherwise
geotagging fails). |
A floating point number |
1800 |
| GeoMaxExtSecs |
Maximum extrapolation time in seconds for
geotagging. Geotagging fails if the Geotime value lies outside a GPS track
by a number of seconds greater than this. Otherwise, the coordinates of the
nearest fix are taken. |
A floating point number |
1800 |
| GeoMaxHDOP |
Maximum Horizontal (2D) Dilution Of Precision
for geotagging. GPS fixes are ignored if the HDOP is greater than this. |
A floating point number, or undef |
undef |
| GeoMaxPDOP |
Maximum Position (3D) Dilution Of Precision for
geotagging. GPS fixes are ignored if the PDOP is greater than this. |
A floating point number, or undef |
undef |
| GeoMinSats |
Minimum number of satellites for geotagging.
GPS fixes are ignored if the number of acquired satellites is less than this. |
A positive integer, or undef |
undef |
| GlobalTimeShift |
Time shift to apply to all extracted
date/time PrintConv values. Does not affect ValueConv values. |
Date/time shift string with leading '-' for negative shifts
(see Image::ExifTool::Shift.pl) |
undef |
| Group# | Extract tags only for specified groups in family #
(Group0 assumed if # not given). |
Group name or reference to list of group names.
Group name may begin with '-' to exclude a group. Case IS significant.
See GetGroup for a description of group families,
and GetAllGroups for a list of available groups. |
undef |
| HtmlDump | Dump information in hex to a dynamic HTML web page.
Option value sets a limit on the maximum block size. Output file is
specified by the TextOut option. |
| 0 = | No HTML dump |
| 1 = | 1 KB size limit |
| 2 = | 16 KB size limit |
| 3 = | Full dump |
| 0 |
| HtmlDumpBase | Base for HTML dump
offsets. If not defined, the EXIF/TIFF base offset is used. |
| 0 = | Absolute offsets |
| non‑zero = | Relative offsets |
| undef = | EXIF/TIFF offsets |
| undef |
| IgnoreMinorErrors | Flag to ignore minor errors. Causes minor
errors to be downgraded to warnings, and minor warnings to be ignored. This
option is provided mainly to allow writing of files when minor errors occur,
but by ignoring some minor warnings the behaviour of ExifTool may be changed
to allow some questionable operations to proceed (such as extracting
thumbnail and preview images even if they don't have a recognizable header).
Minor errors/warnings are denoted by "[minor]" at the start of the message,
or "[Minor]" (with a capital "M") for warnings that affect processing when
ignored. |
0 or 1 | undef |
| Lang | Localized language for exiftool tag descriptions, etc. If the
specified language isn't available, the option is not changed. May be set to
undef to select the built-in default language. |
Image::ExifTool::Lang module name (eg. 'fr', 'zh_cn'), or 'en' or undef for the default language. |
'en' |
| LargeFileSupport | Flag to indicate that 64-bit file offsets are supported on this system. |
0 or 1 | undef |
| List | Flag to extract lists of PrintConv values into arrays instead of combining
them into a string of values. | 0 or 1 | undef |
| ListItem | Return only a specific item from
List-type values. A value of 0 returns the first item in each list, 1 returns
the second item, etc. Negative indices may also be used, with -1 representing the
last item in the list. Applies only to the top-level list of nested lists. |
An integer, or undef | undef |
| ListSep | Separator string used to join lists of PrintConv values when
List option is not set. | Any string | ', ' |
| ListSplit | Regular expression used to split values of list-type tags
into individual items when writing. (eg. use ',\\s*' to split a comma-separated list) |
A regular expression pattern | undef |
| MakerNotes | Option to extract MakerNotes and other writable
subdirectories (such as PrintIM) as a data block. Normally when the MakerNotes
are extracted they are rebuilt to include data outside the boundaries of the
original maker note data block, but a value of 2 disables this feature. |
| 0 = | Don't extract writable subdirectories |
| 1 = | Extract and rebuild makernotes into self-contained block |
| 2 = | Extract without rebuilding makernotes |
| undef |
| MDItemTags | Flag to extract the OS X
metadata item tags (see the "mdls" man page for details). |
0 or 1 | undef |
| MissingTagValue | Value for missing tags in
expressions evaluated by SetNewValuesFromFile.
If not set, a minor error is issued for missing values, or the value
is set to '' if IgnoreMinorErrors is set. |
Any string, or undef | undef |
| NoPDFList | Flag to avoid splitting PDF List-type tag
values into separate items. |
0 or 1 | undef |
| Password | Password for reading/writing
password-protected PDF documents. Ignored if a password is not required. Character encoding of
the password is determined by the value of the Charset option at processing time. |
Any string | undef |
| PNGEarlyXMP | Flag to write XMP in PNG
images before the IDAT (image data) chunk. By default, ExifTool adds new
XMP to the end of a PNG file (just before IEND). This is allowed by the PNG
and XMP specifications, but some utilities seem to ignore XMP if it comes
after the image data. The PNGEarlyXMP option causes ExifTool to instead add
new XMP before the PNG IDAT chunk. However, since ExifTool uses a
single-pass writing algorithm, it has no way to tell if XMP already exists
later in the file before writing the new XMP in this location. If this
happens, a minor error is issued when the extra XMP is encountered, and the
file is not written. Adding the IgnoreMinorErrors
option causes the XMP after IDAT to be deleted, thus resolving the conflict
(at the expense of possible metadata loss), and allowing the file to be
written. The PNGEarlyXMP option is applied automatically when deleting all
XMP and writing new XMP back in one step. When reading, this option causes
a warning to be issued if standard XMP is found after the IDAT chunk. |
0 or 1 | undef |
| PrintConv | Flag to enable print conversion. Also enables inverse print
conversion for writing. | 0 or 1 | 1 |
| QuickTimeUTC | Flag set to assume that QuickTime
date/time values are stored as UTC, causing conversion to local time when they are
extracted. According to the QuickTime specification date/time values should be UTC,
but many digital cameras store local time instead (presumably because they don't know
the time zone). This option also disables the autodetection of incorrect time-zero
offsets in QuickTime date/time values, and enforces a time zero of 1904 as per the
QuickTime specification. | 0 or 1 | undef |
| RequestAll | Flag to request all tags to be extracted.
This causes some tags to be generated which normally would not be unless specifically
requested (by passing the tag name to ImageInfo or
ExtractInfo). Note that this flag is set automatically
during a call to SetNewValuesFromFile to
make all tags available for copying. | 0 or 1 | undef |
| RequestTags | List of additional tags to request in
next call to ExtractInfo. This option is useful only for
tags which aren't extracted unless specifically requested. | List reference,
delimited string of tag names (any delimiter is allowed), or undef to clear the
previous RequestTags list. Case is not significant. | undef |
| ScanForXMP | Flag to scan all files (even unrecognized
formats) for XMP information unless XMP was already found in the file. When combined with
the FastScan option, only unrecognized file types are scanned for XMP.
| 0 or 1 | undef |
| Sort | Specifies order to sort tags in the returned tag list. |
| Input = | Sort in same order as input tag arguments |
| File = | Sort in order that tags were found in the file |
| Tag = | Sort alphabetically by tag name |
| Descr = | Sort by tag description (with current Lang setting) |
| Group# = | Sort by tag group,
where # is zero or more family numbers separated by colons. If # is not specified,
Group0 is assumed. See GetGroup for a description of group
families. |
| 'Input' |
| Sort2 | Secondary sort order used for tags within each group when Sort is 'Group'. |
| File = | Sort in order that tags were found in the file |
| Tag = | Sort alphabetically by tag name |
| Descr = | Sort by tag description (with current Lang setting) |
| 'File' |
| StrictDate | Flag to return undefined value for any date which can't be
converted when the DateFormat option is used. |
0 or 1 | undef |
| Struct | Flag to return XMP structures as HASH references
instead of flattening into individual tags. This setting has no effect
when writing since both flattened or structured tags may always be written.
See the Structured Information documentation for
more details about structured information. |
| undef = | Same as 0 for reading and 2 for copying |
| 0 = | Read/copy flattened tags |
| 1 = | Read/copy structures |
| 2 = | Read/copy both flattened and structured tags,
but flag flattened tags as "unsafe" for copying |
| undef |
| SystemTags | Flag to extract the
following additional File System tags: FileAttributes, FileDeviceNumber,
FileInodeNumber, FileHardLinks, FileUserID, FileGroupID, FileDeviceID,
FileBlockSize and FileBlockCount. |
0 or 1 | undef |
| TextOut | Output file for Verbose and HtmlDump options. |
File reference | \*STDOUT |
| Unknown | Control extraction of unknown tags. |
| 0 = | Unknown tags not extracted |
| 1 = | Unknown tags are extracted from EXIF
(and other tagged-format) directories |
| 2 = | Unknown tags also extracted from binary data blocks |
| 0 |
| UserParam | Special option to set/get user-defined parameters.
Useful to allow external input into tag name expressions and ValueConv logic.
PARAM is the user-defined parameter name (case insensitive). These parameters
may be accessed in tag name expressions by prefixing the parameter name with a dollar
sign, just like normal tags. If called without a parameter name,
Options('UserParam') returns a reference to the hash of all user
parameters (with lower-case names).
|
| PARAM | - Get parameter |
| PARAM= | - Clear parameter |
| PARAM=VALUE | - Set parameter |
| { } |
| Verbose | Print verbose messages to file specified by TextOut option.
Click here for example outputs. |
| 0 = | No verbose messages |
| 1 = | Print tag names and raw values |
| 2 = | Add additional tag details |
| 3 = | Add hex dump of tag data (with length limits) |
| 4 = | Remove length limit on dump of tag values |
| 5 = | Remove length limit on dump of JPEG segments |
| 0 |
| WriteMode | Set tag write/create mode. |
A string with one or more of these characters:
| w = | Write existing tags |
| c = | Create new tags |
| g = | Create new groups † |
| 'wcg' |
| XMPAutoConv | Flag to enable automatic conversion
for unknown XMP tags with values that look like rational numbers or dates. |
0 or 1 |
1 |
| † | The level of
the group differs for different types of metadata. For XMP or IPTC this is the
full XMP/IPTC block (the family 0 group), but for EXIF this is the individual
IFD (the family 1 group). |
Examples:
# exclude the 'OwnerName' tag from returned information
$exifTool->Options(Exclude => 'OwnerName');
|
# only get information in EXIF or MakerNotes groups
$exifTool->Options(Group0 => ['EXIF', 'MakerNotes']);
|
# ignore information from IFD1
$exifTool->Options(Group1 => '-IFD1');
|
# sort by groups in family 2, and extract unknown tags
$exifTool->Options(Sort => 'Group2', Unknown => 1);
|
# reset DateFormat option
$exifTool->Options(DateFormat => undef);
|
# do not extract duplicate tag names
$oldSetting = $exifTool->Options(Duplicates => 0);
|
# get current Verbose setting
$isVerbose = $exifTool->Options('Verbose');
|
# set a user parameter
$exifTool->Options(UserParam => 'MyParam=some value');
|
Reset all options to their default values. Loads user-defined default
option values from the %Image::ExifTool::UserDefined::Options hash in
the .ExifTool_config file if it exists.
| Prototype | ClearOptions() |
| Inputs | 0) ExifTool object reference
|
Extract all meta information from an image.
| Prototype | ExtractInfo($;@) |
| Inputs | 0) ExifTool object reference
1-N) Same as ImageInfo except that a list of tag
keys is not returned if an ARRAY reference is given.
|
| Returns | 1 if this was a recognized file format, 0 otherwise |
Example:
$success = $exifTool->ExtractInfo('image.jpg', \%options);
|
The following options are effective in the call to ExtractInfo:
Binary, Charset, CharsetEXIF, CharsetFileName, CharsetID3, CharsetIPTC,
CharsetQuickTime, Composite, ExtendedXMP, ExtractEmbedded, FastScan,
FixBase, HtmlDump, HtmlDumpBase, IgnoreMinorErrors, Lang, LargeFileSupport,
MakerNotes, NoPDFList, PNGEarlyXMP, ScanForXMP, Struct, SystemTags, TextOut,
Unknown and Verbose.
GetInfo is called to return meta information
after it has been extracted from the image by a previous call to
ExtractInfo or ImageInfo.
This function may be called repeatedly after a single call to
ExtractInfo or ImageInfo.
| Prototype | GetInfo($;@) |
| Inputs | 0) ExifTool object reference
1-N) Same as ImageInfo except that an image
can not be specified
|
| Returns | Reference to information hash, the same as with
ImageInfo |
Examples:
# get image width and height only
$info = $exifTool->GetInfo('ImageWidth', 'ImageHeight');
|
# get all Error and Warning messages
$info = $exifTool->GetInfo('Error', 'Warning');
|
# get information for all tags in list (list updated with tags found)
$info = $exifTool->GetInfo(\@ioTagList);
|
# get all information in Author or Location groups
$info = $exifTool->GetInfo({Group2 => ['Author', 'Location']});
|
The following options are effective in the call to GetInfo:
Charset, CoordFormat, DateFormat, Duplicates, Escape, Exclude, Filter, Group#,
GlobalTimeShift, Lang, List, ListItem, ListSep, PrintConv, Sort (if a tag
list reference is given) and StrictDate.
Write meta information to a file. The specified source file is rewritten to
the same-type destination file with new information as specified by previous
calls to SetNewValue. The necessary segments and/or
directories are created in the destination file as required to store the
specified information. May be called repeatedly to write the same information
to additional files without the need to call SetNewValue
again.
| Prototype | WriteInfo($$;$$) |
| Inputs | 0) ExifTool object reference
1) Source file name, file reference, scalar reference, or undef to
create a file from scratch. A reference to a File::RandomAccess object is
also allowed as a source, but in this case the destination is not optional.
2) [optional] Destination file name, file reference, scalar
reference, or undef to overwrite the original file. May be '-' to write to
stdout.
3) [optional] Destination file type. Ignored if a source
is defined.
|
| Returns | 1 if file was written OK, 2 if file was written
but no changes made, 0 on file write error.
|
The source file name may be undefined to create a file from scratch
(currently only XMP, MIE, ICC, VRD, DR4, EXV and EXIF files can be created
in this way -- see CanCreate for details).
If undefined, the destination file type is required unless the type can be
determined from the extension of the destination file name.
If a destination file name is given, the specified file must not exist
because an existing destination file will not be overwritten. Any new
values for FileName, Directory or HardLink are ignored when a destination
file name is specified.
The destination file name may be undefined to overwrite the original file
(make sure you have backups!). In this case, if a source file name is
provided, a temporary file is created and renamed to replace the source file
if no errors occurred while writing. Otherwise, if a source file reference
or scalar reference is used, the image is first written to memory then
copied back to replace the original if there were no errors.
On Mac OS systems, the file resource fork is preserved if this routine
is called with a source file name.
Examples:
# add information to a source file, writing output to new file
my $result = $exifTool->WriteInfo($srcfile, $dstfile);
|
# create XMP data file from scratch
$exifTool->WriteInfo(undef, $dstfile, 'XMP');
|
# overwrite file (you do have backups, right?)
$exifTool->WriteInfo($srcfile);
|
# retrieve error and warning messages
$errorMessage = $exifTool->GetValue('Error');
$warningMessage = $exifTool->GetValue('Warning');
|
If an error code is returned, an Error tag is set and GetValue('Error') can
be called to obtain the error description. A Warning tag may be set even if
this routine is successful. Calling WriteInfo clears any pre-existing Error
and Warning tags.
The following ExifTool options are effective in the call to
WriteInfo:
ByteOrder, Charset, CharsetEXIF, CharsetFileName, CharsetIPTC, Compact,
Compress, FixBase, IgnoreMinorErrors, PNGEarlyXMP and Verbose.
Get a sorted list of tags from the specified information hash or tag list.
| Prototype | GetTagList($;$$$) |
| Inputs | 0) ExifTool object reference
1) [optional] Reference to info hash or tag list
2) [optional] Sort order ('Input', 'File', 'Tag', 'Descr' or 'Group#')
3) [optional] Secondary sort order ('File', 'Tag' or 'Descr')
|
| Returns | List of tag keys in specified order |
Example:
@tags = $exifTool->GetTagList($info, 'Group0');
|
If the information hash or tag list reference is not provided, then the list
of found tags from the last call to ImageInfo,
ExtractInfo or GetInfo
is used instead, and the result is the same as if
GetFoundTags was called. If sort order is not
specified, the sort order is taken from the current options settings.
Get list of found tags in specified sort order. The found tags are the
tags for the information obtained from the most recent call to
ImageInfo, ExtractInfo
or GetInfo for this object.
| Prototype | GetFoundTags($;$$) |
| Inputs | 0) ExifTool object reference
1) [optional] Sort order ('Input', 'File', 'Tag', 'Descr' or 'Group#')
2) [optional] Secondary sort order ('File', 'Tag' or 'Descr')
|
| Returns | List of tag keys in the specified order |
Example:
my @tags = $exifTool->GetFoundTags('File');
|
Get list of requested tags. These are the tags that were specified
in the arguments of the most recent call to ImageInfo,
ExtractInfo or GetInfo,
including tags specified via a tag list reference. They are returned
in the same order that they were specified. Shortcut tags are expanded
in the list.
| Prototype | GetRequestedTags($) |
| Inputs | 0) ExifTool object reference
|
| Returns | List of tag keys for requested tags
(empty if no tags specifically requested) |
Example:
my @requestedTags = $exifTool->GetRequestedTags();
|
Get the value of a specified tag. The returned value is either the
human-readable (PrintConv) value, the converted machine-readable (ValueConv)
value, or the original raw (Raw) value. If the value type is not specified,
the PrintConv value is returned if the PrintConv option is set, otherwise the
ValueConv value is returned. The PrintConv values are the same as the values
returned by ImageInfo and GetInfo
in the tag/value hash unless the PrintConv option is disabled.
Tags which represent lists of multiple values (as may happen with
'Keywords' for example) are handled specially. In scalar context,
the returned PrintConv value for these tags is either a string of values or
a list reference (depending on the List option setting), and the ValueConv
value is always a list reference. But in list context,
GetValue always returns the list itself.
Note that GetValue requires a case-sensitive tag key
as an argument. To retrieve tag information based on a case-insensitive tag name
(with an optional group specifier), use GetInfo
instead.
| Prototype | GetValue($$;$) |
| Inputs | 0) ExifTool object reference
1) Tag key
2) [optional] Value type, 'PrintConv', 'ValueConv', 'Both',
'Raw' or 'Rational'
The default value type is 'PrintConv' if the PrintConv option
is set, otherwise the default is 'ValueConv'. A value type of 'Both'
returns both ValueConv and PrintConv values as a list. 'Rational' returns
the raw rational value as a string fraction for rational types, or undef for
other types.
|
| Returns |
The value of the specified tag. If the tag represents a list of multiple values
and the List option is disabled then PrintConv returns a string of values,
otherwise a reference to the list is returned in scalar context. The list
itself is returned in list context. (Unless 'Both' values are requested, in
which case two list references are returned, regardless of context.) Values may
also be scalar references to binary data, or hash references if the
Struct option is set.
Note: It is possible
for GetValue to return an undefined ValueConv or
PrintConv value (or an empty list in list context) even if the tag exists, since
it is possible for these conversions to yield undefined values. And the
Rational value will be undefined for any non-rational tag. The Raw value should
always exist if the tag exists.
|
Examples:
# PrintConv example
my $val = $exifTool->GetValue($tag);
if (ref $val eq 'SCALAR') {
print "$tag = (unprintable value)\n";
} else {
print "$tag = $val\n";
}
|
# ValueConv example
my $val = $exifTool->GetValue($tag, 'ValueConv');
if (ref $val eq 'ARRAY') {
print "$tag is a list of values\n";
} elsif (ref $val eq 'SCALAR') {
print "$tag represents binary data\n";
} else {
print "$tag is a simple scalar\n";
}
|
# list example
my @keywords = $exifTool->GetValue('Keywords', 'ValueConv');
|
The following options are in effect when GetValue is
called:
Charset, CoordFormat, DateFormat, Escape, Filter, GlobalTimeShift, Lang, List,
ListItem, ListSep, PrintConv and StrictDate.
Set the new value for a tag. The routine may be called multiple times to set
the values of many tags before using WriteInfo to write
the new values to an image.
For list-type tags (like Keywords), either call repeatedly with
the same tag name for each value, or call with a reference to the list of values.
| Prototype | SetNewValue($;$$%) |
| Inputs | 0) ExifTool object reference
1) [optional] Tag key or tag name, or undef to clear all new
values. The tag name may be prefixed one or more family 0, 1 or 2 group
names with optional leading family numbers, separated by colons (eg.
'EXIF:Artist', 'XMP:Time:*'), which is equivalent
to using a Group option argument. Also, a '#' may be appended
to the tag name (eg. 'EXIF:Orientation#'), with the same effect
as setting Type to 'ValueConv'. Wildcards ('*' and
'?') may be used in the tag name to assign multiple tags
simultaneously A tag name of '*' is special when deleting
information, and will delete an entire group even if some individual tags in
the group are not writable, but only if a single family 0 or 1 group name is
specified (otherwise, the tags are deleted individually). Use
GetDeleteGroups to get a list of deletable group
names, and see the TagNames documentation
for a complete list of ExifTool tag names.
2) [optional] New value for tag. Undefined to delete tag
from file. May be a scalar, scalar reference, list reference to set a list
of values, or hash reference for a structure. Integer values may be
specified as a hexadecimal string (with a leading '0x'), and simple
rational values may be specified in fractional form (eg. '4/10'). Structure
tags may be specified either as a hash reference or a serialized string
(see the last two examples below).
3-N) [optional] SetNewValue option/value pairs (see below).
|
| Returns | Scalar context: The number of tags set, and
errors are printed to STDERR.
List context: The number of tags set, and the error string (undefined if no error).
|
| SetNewValue Options |
|---|
| Option | Description | Values | Default |
|---|
| AddValue | Add value to existing list in a file rather than overwriting |
| 0 = | Overwrite existing value(s) |
| 1 = | Add to existing list, or warn for non-list tags |
| 2 = | Add to existing list, or overwrite non-list tags |
| 0 |
| DelValue | Delete existing tag from a file if it has the specified value |
0 or 1 | 0 |
| EditGroup | Create tags in existing groups only. Don't create new group.
Effectively removes the 'g' from the ExifTool WriteMode option for this tag only. |
0 or 1 | 0 |
| EditOnly | Edit tag only if it already exists. Don't create new tag.
Effectively removes the 'c' from the ExifTool WriteMode option for this tag only. |
0 or 1 | 0 |
| Group | Specifies group name where tag should be written.
If not specified, tag is written to highest priority group as specified
by SetNewGroups. Case is not significant |
One or more family 0, 1 or 2 groups with optional leading
family number, separated by colons | undef |
| NoFlat | Treat flattened tags as 'unsafe' | 0 or 1 | 0 |
| NoShortcut | Disables default behaviour of looking up tag in
shortcuts if not found otherwise. | 0 or 1 | 0 |
| Protected | Allow protected tags to be written |
Bitmask of tag protection levels to write:
| 0 |
| ProtectSaved | Avoid setting new values which were saved after the Nth
call to SaveNewValues. Has no effect on unsaved values,
or values saved before the Nth call. | N | undef |
| Replace | Replace previous new values for this tag (ie. replace the values
set in previous calls to SetNewValue). This option
is most commonly used to replace previously-set new values for list-type tags. |
| 0 = | Set new value normally |
| 1 = | Reset previous new values and replace with the specifed new value |
| 2 = | Reset previous new values only |
| 0 |
| Shift | Shift the tag by the specified value. Currently only date/time tags
and tags with numerical values may be shifted. Value is added if Shift is 1, or subtracted
if Shift is -1. See Image::ExifTool::Shift.pl for details time shift formats. |
| undef = No shift |
| 0 = | Shift if shiftable:
Positive if AddValue set, or
Negative if DelValue set and
tag is date/time |
| 1 = | Positive shift |
| -1 = | Negative shift |
| undef |
| Type | The type of value being set |
PrintConv, ValueConv or Raw (default depends on PrintConv Option) |
PrintConv or ValueConv |
Examples:
# set a new value for a tag (errors go to STDERR)
$success = $exifTool->SetNewValue($tag, $value);
|
# set a new value and capture any error message
($success, $errStr) = $exifTool->SetNewValue($tag, $value);
|
# delete information for specified tag if it exists in image
# (also resets AddValue and DelValue options for this tag)
$exifTool->SetNewValue($tag);
|
# reset all values from previous calls to SetNewValue()
$exifTool->SetNewValue();
|
# delete a specific keyword
$exifTool->SetNewValue('Keywords', $word, DelValue => 1);
|
# set keywords (a list-type tag) with two new values
$exifTool->SetNewValue(Keywords => 'word1');
$exifTool->SetNewValue(Keywords => 'word2');
# equivalent, but set both in one call using an array reference
$exifTool->SetNewValue(Keywords => ['word1','word2']);
|
# add a keyword without replacing existing keywords in the file
$exifTool->SetNewValue(Keywords => $word, AddValue => 1);
|
# set a tag in a specific group
$exifTool->SetNewValue(Headline => $val, Group => 'XMP');
$exifTool->SetNewValue('XMP:Headline' => $val); # (equivalent)
|
# shift original date/time back by 2.5 hours
$exifTool->SetNewValue(DateTimeOriginal => '2:30', Shift => -1);
|
# write a tag only if it had a specific value
# (the order of the following calls is not significant)
$exifTool->SetNewValue(Title => $oldVal, DelValue => 1);
$exifTool->SetNewValue(Title => $newVal);
|
# write tag by numerical value
$exifTool->SetNewValue(Orientation => 6, Type => 'ValueConv');
$exifTool->SetNewValue('Orientation#' => 6); # (equivalent)
|
# delete all but EXIF tags
$exifTool->SetNewValue('*'); # delete all...
$exifTool->SetNewValue('EXIF:*', undef, Replace => 2); # ...but EXIF
|
# write structured information as a HASH reference
$exifTool->SetNewValue('XMP:Flash' => { mode=>'on', fired=>'true', return=>'not' });
|
# write structured information as a serialized string
$exifTool->SetNewValue('XMP:Flash' => '{mode=on,fired=true,return=not}');
|
(see struct.html for a
description of the structure serialization technique)
Notes:
When deleting groups of tags, the Replace option may be used to exclude
specific groups from a mass delete. However, this technique may not be used to
exclude individual tags from a group delete (unless a family 2 group was
specified in the delete). Instead, use
SetNewValuesFromFile to recover the values
of individual tags after deleting a group.
When deleting all tags from a JPEG image, the APP14 "Adobe" information is
not deleted by default because doing so may affect the appearance of the image.
However, this information may be deleted by specifying it explicitly, either by
group (with 'Adobe:*') or as a block (with 'Adobe').
The following ExifTool options are effective in the call to
SetNewValue:
Charset, Escape, IgnoreMinorErrors, Lang, ListSep, ListSplit, PrintConv, Verbose
and WriteMode.
Get the new Raw value for a tag. This is the value set by
SetNewValue that is queued to be written to
file. List-type tags may return multiple values in list context.
| Prototype | GetNewValue($$) |
| Inputs | 0) ExifTool object reference
1) Tag name (case sensitive, may be prefixed by family 0 or 1 group name)
|
| Returns | List of new Raw tag values, or first value in
list when called in scalar context. The list may be empty either if the tag
isn't being written, or if it is being deleted (ie. if
SetNewValue was called without a value).
|
Examples:
my $rawVal = $exifTool->GetNewValue($tag);
|
my @rawVals = $exifTool->GetNewValue($tag);
|
A very powerful routine that sets new values for tags from information found
in a specified file.
| Prototype | SetNewValuesFromFile($$;@) |
| Inputs | 0) ExifTool object reference
1) File name, file reference, or scalar reference
2-N) [optional] List of tag names to set or options hash
references. All writable tags are set if none are specified. The tag names
are not case sensitive, and may be prefixed by one or more family 0, 1 or 2
group names with optional leading family numbers, separated by colons (eg.
'exif:iso'). A leading '-' indicates tags to be
excluded (eg. '-comment'), or a trailing '#' causes
the ValueConv value to be copied (same as setting the Type option to
'ValueConv' for this tag only). Wildcards ('*' and
'?') may be used in the tag name. A tag name of '*'
is commonly used when a group is specified to copy all tags in the group (eg.
'XMP:*').
A special feature allows tag names of the
form 'DSTTAG<SRCTAG' (or 'SRCTAG>DSTTAG') to be
specified to copy information to a tag with a different name or a specified
group. Both 'SRCTAG' and 'DSTTAG' may contain
wildcards and/or be prefixed by a group name (eg.
'fileModifyDate<modifyDate' or 'xmp:*<*'),
and/or suffixed by a '#' to disable print conversion. Copied tags
may also be added or deleted from a list with arguments of the form
'DSTTAG+<SRCTAG' or 'DSTTAG-<SRCTAG'. Tags are
evaluated in order, so exclusions apply only to tags included earlier in the
list. An extension of this feature allows the tag value to be set from an
expression containing tag names with leading '$' symbols (eg.
'Comment<the file is $filename'). Braces '{}' may
be used around the tag name to separate it from subsequent text, and a
'$$' is used to to represent a '$' symbol. The
behaviour for missing tags in expressions is defined by the MissingTagValue option. The tag value may be
modified via changes to the default input variable ($_) in Perl
expressions placed inside the braces and after a semicolon following the tag
name. Braces within the expression must be balanced.
Multiple options hash references may be passed to set different options for
different tags. Options apply to subsequent tags in the argument list.
|
| Returns | A hash of information that was set
successfully. May include Warning or Error entries if there were problems
reading the input file.
|
By default, this routine will commute information between same-named tags in
different groups, allowing information to be translated between images with
different formats. This behaviour may be modified by specifying a group name
for extracted tags (even if '*' is used as a group name), in which
case the information is written to the original group, unless redirected to a
different group. When '*' is used for a group name, by default the
family 1 group of the original tag is preserved, but a different family may be
specified with a leading family number. (For example, specifying
'*:*' copies all information while preserving the original family 1
groups, while '0*:*' preserves the family 0 group.)
SetNewValuesFromFile Options:
The options are the same was for SetNewValue, and
are passed directly to SetNewValue internally,
with a few exceptions:
- The Replace option defaults to 1 instead of 0 as with
SetNewValue.
- The AddValue or DelValue option is set for individual tags if '+>' or
'->' (or '+<' or '-<') are used.
- The Group option is set for tags where a group name is given.
- The Protected flag is set to 1 for individually specified tags.
- The Type option also applies to extracted tags.
Examples:
# set new values from all information in a file...
my $info = $exifTool->SetNewValuesFromFile($srcFile);
# ...then write these values to another image
my $result = $exifTool->WriteInfo($file2, $outFile);
|
# set all new values, preserving original groups
$exifTool->SetNewValuesFromFile($srcFile, '*:*');
|
# set specific information
$exifTool->SetNewValuesFromFile($srcFile, $tag1, $tag2...);
|
# set new value from a different tag in specific group
$exifTool->SetNewValuesFromFile($src, 'IPTC:Keywords>XMP-dc:Subject');
|
# add all IPTC keywords to XMP subject list
$exifTool->SetNewValuesFromFile($src, 'IPTC:Keywords+>XMP-dc:Subject');
|
# set new value from an expression involving other tags
$exifTool->SetNewValuesFromFile($file,
'Comment<ISO=$ISO Aperture=$aperture Exposure=$shutterSpeed');
|
# set keywords list from the values of multiple tags
$exifTool->SetNewValuesFromFile($file, { Replace => 0 },
'keywords<xmp:subject', 'keywords<filename');
|
# copy all EXIF information, preserving the original IFD
# (without '>*.*' tags would be copied to the preferred EXIF IFD)
$exifTool->SetNewValuesFromFile($file, 'EXIF:*>*:*');
|
# copy all tags with names starting with "gps" (note: this is
# different than "gps:*" because it will also copy XMP GPS tags)
$exifTool->SetNewValuesFromFile($file, 'gps*');
|
# set FileName from Model, translating questionable characters to underlines
$exifTool->SetNewValuesFromFile($file, 'filename<${model;tr(/\\\\?*:|"<>)(_)}.jpg');
|
Notes:
The PrintConv option applies to this routine, but it normally should be left
on to provide more reliable transfer of information between groups.
If a preview image exists, it is not copied. The preview image must be
transferred separately if desired, in a separate call to
WriteInfo
When simply copying all information between files of the same type, it is
usually desirable to preserve the original groups by specifying
'*:*' for the tags to set.
The Duplicates option is always in effect for tags
extracted from the source file using this routine.
The Struct option is enabled by default for tags
extracted by this routine. This allows the hierarchy of complex structures to
be preserved when copying, but the Struct option may be set to 0 to override
this behaviour and copy as flattened tags instead.
Return the total number of new values set.
| Prototype | CountNewValues($) |
| Inputs | 0) ExifTool object reference
|
| Returns | In scalar context, returns the total number
of tags with new values set. In list context, also returns the number of
"pseudo" tag values which have been set. "Pseudo" tags are tags like FileName
and FileModifyDate which are not contained within the file and can be changed
without rewriting the file. |
Examples:
my $numSet = $exifTool->CountNewValues();
|
my ($numSet, $numPseudo) = $exifTool->CountNewValues();
|
Save state of new values to be later restored by RestoreNewValues.
| Prototype | SaveNewValues($) |
| Inputs | 0) ExifTool object reference
|
| Returns | Count of the number of times this routine has
been called (N) since the last time the new values were reset. |
Example:
$exifTool->SaveNewValues(); # save state of new values
$exifTool->SetNewValue(ISO => 100); # set new value for ISO
$exifTool->WriteInfo($src, $dst1); # write ISO plus any previous new values
$exifTool->RestoreNewValues(); # restore previous new values
$exifTool->WriteInfo($src, $dst2); # write previous new values only
|
Restore new values to the settings that existed when
SaveNewValues was last called. May be called
repeatedly after a single call to SaveNewValues.
See SaveNewValues above for an example.
| Prototype | RestoreNewValues($) |
| Inputs | 0) ExifTool object reference
|
Write the filesystem modification or creation time from the new value of the
FileModifyDate or FileCreateDate tag.
| Prototype | SetFileModifyDate($$;$$) |
| Inputs | 0) ExifTool object reference
1) File name
2) [optional] Base time if applying shift (in days before $^T)
3) [optional] Tag to write: 'FileModifyDate' (default), or 'FileCreateDate'
|
| Returns | 1 if the time was changed, 0 if nothing was
done, or -1 if there was an error setting the time.
|
Example:
$exifTool->SetNewValue(FileModifyDate => '2000:01:02 03:04:05', Protected => 1);
my $result = $exifTool->SetFileModifyDate($file);
|
Notes:
Equivalent to, but more efficient than calling WriteInfo
when only the FileModifyDate or FileCreateDate tag has been set. If a timezone is not
specified, local time is assumed. When shifting, the time of the original
file is used unless the optional base time is specified.
The ability to write FileCreateDate is currently restricted to Windows systems only.
Set the file name and directory, or create a hard link to the file. If not
specified, the new file name is derived from the new values of the FileName and
Directory tags, or from the HardLink tag if creating a link. If the FileName
tag contains a '/', then the file is renamed into a new directory.
If FileName ends with '/', then it is taken as a directory name and
the file is moved into the new directory. The new value for the Directory tag
takes precedence over any directory specified in FileName.
| Prototype | SetFileName($$;$$) |
| Inputs | 0) ExifTool object reference
1) Current file name
2) [optional] New file name
3) [optional] 'Link' to create a hard link instead of renaming the file,
or 'Test' to test renaming feature by printing the old and new names instead of
changing anything.
|
| Returns | 1 if the file name or directory was changed,
0 if nothing was done, or -1 if there was an error renaming the file.
|
Examples:
my $result = $exifTool->SetFileName($file);
|
my $result = $exifTool->SetFileName($file, $newName);
|
Notes:
Will not overwrite existing files. New directories are created as
necessary.
Set the order of the preferred groups when adding new information. In
subsequent calls to SetNewValue, new information
will be created in the first valid group of this list. This has an impact
only if the group is not specified when calling
SetNewValue, and if the tag name exists in more
than one group. The default order is EXIF, IPTC then XMP. Any family 0
group name may be used. Case is not significant.
| Prototype | SetNewGroups($;@) |
| Inputs | 0) ExifTool object reference
1-N) Groups in order of priority. If no groups are specified, the
priorities are reset to the defaults.
|
Example:
$exifTool->SetNewGroups('XMP','EXIF','IPTC');
|
Get current group priority list.
| Prototype | GetNewGroups($) |
| Inputs | 0) ExifTool object reference
|
| Returns | List of group names in order of write
priority. Highest priority first.
|
Example:
@groups = $exifTool->GetNewGroups();
|
Get the ID for the specified tag. The ID is the IFD tag number in EXIF
information, the property name in XMP information, or the data offset in a
binary data block. For some tags, such as Composite tags where there is no ID,
an empty string is returned. In list context, also returns a language code for
the tag if available and different from the default language (eg. with
alternate language entries for XMP "lang-alt" tags).
| Prototype | GetTagID($$) |
| Inputs | 0) ExifTool object reference
1) Tag key
|
| Returns | In scalar context, returns the tag ID or '' if
there is no ID for this tag.
In list context, returns the tag ID (or '') and the
language code (or undef). |
Examples:
my $id = $exifTool->GetTagID($tag);
|
my ($id, $lang) = $exifTool->GetTagID($tag);
|
Get description for specified tag. This function will always return a defined
value. In the case where the description doesn't exist, one is generated from
the tag name.
| Prototype | GetDescription($$) |
| Inputs | 0) ExifTool object reference
1) Tag key
|
| Returns | Tag description |
Get group name(s) for a specified tag.
| Prototype | GetGroup($$;$) |
| Inputs | 0) ExifTool object reference
1) Tag key
2) [optional] Group family number, or string of numbers
separated by colons
|
| Returns | Group name (or '' if tag has no
group). If no group family is specified, returns the name of group in family 0
when called in scalar context, or the names of groups for all families in list
context. Returns a string of group names separated by colons if the input group
family contains a colon. The string is simplified to remove a leading 'Main:'
and adjacent identical group names unless the family string begins with a colon.
|
The following families of groups are available:
| Family | Description | Examples |
|---|
| 0 | Information Type | EXIF, XMP, IPTC |
| 1 | Specific Location | IFD0, XMP-dc |
| 2 | Category | Author, Time |
| 3 | Document Number | Main, Doc1, Doc3-2 |
| 4 | Instance Number | Copy1, Copy2, Copy3... |
Families 0 and 1 are based on the file structure, and are similar except that
family 1 is more specific and sub-divides some groups to give more detail about
the specific location where the information was found. For example, the EXIF
group is split up based on the specific IFD (Image File Directory), the
MakerNotes group is divided into groups for each manufacturer, and the XMP group
is separated based on the XMP namespace prefix. Note that only common XMP
namespaces are listed in the GetAllGroups
documentation, but additional namespaces may be present in some XMP data. Also
note that the 'XMP-xmp...' group names may appear in the older form
'XMP-xap...' since these names evolved as the XMP standard was
developed. The ICC_Profile group is broken down to give information about the
specific ICC_Profile tag from which multiple values were extracted. As well,
information extracted from the ICC_Profile header is separated into the
ICC-header group.
Family 2 classifies information based on the logical category to which the
information refers.
Family 3 gives the document number for tags extracted from embedded documents,
or 'Main' for tags from the main document. (See the
ExtractEmbedded option for extracting tags from embedded
documents.) Nested sub-documents (if they exist) are indicated by numbers
separated with dashes in the group name, to an arbitrary depth. (eg.
'Doc2-3-1' is the 1st sub-sub-document of the
3rd sub-document of the 2nd embedded document of the main
file.)
Family 4 provides a method for differentiating tags when multiple tags exist
with the same name in the same location. The primary instance of a tag (the tag
extracted when the Duplicates option is disabled and no group is specified) has
no family 4 group name, but additional instances have have family 4 group names
of 'Copy1', 'Copy2', 'Copy3', etc.
See GetAllGroups for lists of group names.
Examples:
# return family 0 group name (eg. 'EXIF')
$group = $exifTool->GetGroup($tag, 0);
|
# return all groups (eg. qw{EXIF IFD0 Author Main})
@groups = $exifTool->GetGroup($tag);
|
# return groups as a string (eg. 'Main:IFD0:Author')
$group = $exifTool->GetGroup($tag, ':3:1:2');
|
# return groups as a simplified string (eg. 'IFD0:Author')
$group = $exifTool->GetGroup($tag, '3:1:2');
|
Get list of group names for all tags in specified information hash.
| Prototype | GetGroups($;$$) |
| Inputs | 0) ExifTool object reference
1) [optional] Information hash reference (default is all extracted info)
2) [optional] Group family number (default 0)
|
| Returns |
List of group names in alphabetical order.
If information hash is not specified, the group names are returned for
all extracted information. See GetAllGroups for
a list of groups in each family.
|
Examples:
my @groups = $exifTool->GetGroups($info, $family);
|
Example of one way to print information organized by group
my $exifTool = new Image::ExifTool;
$exifTool->ExtractInfo('t/images/ExifTool.jpg');
my $family = 1;
my @groups = $exifTool->GetGroups($family);
my $group;
foreach $group (@groups) {
print "---- $group ----\n";
my $info = $exifTool->GetInfo({"Group$family" => $group});
foreach ($exifTool->GetTagList($info)) {
print "$_ : $$info{$_}\n";
}
}
|
Builds composite tags from required tags. The composite tags are convenience
tags which are derived from the values of other tags. This routine is called
automatically by ImageInfo if the Composite option is set.
| Prototype | BuildCompositeTags($) |
| Inputs | 0) ExifTool object reference
|
| Returns | (none) |
Notes:
- Tag values are calculated in alphabetical order unless a tag Require's
or Desire's another composite tag, in which case the calculation is
deferred until after the other tag is calculated.
- Composite tags may need to read data from the image for their value to be
determined, and for these BuildCompositeTags
must be called while the image is available. This is only a problem if
ImageInfo is called with a filename (as opposed to a
file reference or scalar reference) since in this case the file is closed before
ImageInfo returns. Here the Composite option may be
used so that BuildCompositeTags is called from
within ImageInfo, before the file is closed.
|
The following functions access only static data and are not called with an
ExifTool object
|
The names of all the following functions, plus
ImageInfo, may be imported into the current namespace
with the "Public" tag. When this is done, the functions can be accessed without
the need to prefix the function name with "Image::ExifTool::". For
example:
use Image::ExifTool ':Public';
$tagName = GetTagName($tag);
|
Get name of tag from tag identifier. This is a convenience function that
strips the embedded instance number, if it exists, from the tag key.
| Prototype | GetTagName($) |
| Inputs | 0) Tag key
|
| Returns | Tag name |
Example:
$tagName = Image::ExifTool::GetTagName($tag);
|
Get list of tag shortcut names.
| Prototype | GetShortcuts() |
| Inputs | (none)
|
| Returns | List of shortcuts |
Get list of all available tag names.
| Prototype | GetAllTags(;$) |
| Inputs | 0) [optional] Group name,
or string of group names separated by colons
|
| Returns | A list of all available tags in alphabetical
order, or all tags in a specified group or intersection of groups. The
group name is case insensitive, and any group in families 0-2 may be used
except for EXIF family 1 groups (ie. the specific IFD).
|
Get list of all writable tag names.
| Prototype | GetWritableTags(;$) |
| Inputs | 0) [optional] Group name,
or string of group names separated by colons
|
| Returns | A list of all writable tags in alphabetical
order. These are the tags for which values may be set through
SetNewValue. If a group name is given, returns
only writable tags in specified group(s). The group name is case insensitive,
and any group in families 0-2 may be used except for EXIF family 1 groups (ie.
the specific IFD).
|
Get list of all group names in specified family.
| Prototype | GetAllGroups($) |
| Inputs | 0) Group family number (0-4)
|
| Returns |
A list of all groups in the specified family in alphabetical order |
Here is a complete list of groups for each family:
| Family | Group Names |
|---|
| 0 (Information Type) |
AFCP, AIFF, APE, APP0, APP1, APP11, APP12, APP13, APP14, APP15, APP4, APP5,
APP6, APP8, ASF, Audible, CanonVRD, Composite, DICOM, DNG, DV, DjVu, Ducky,
EXE, EXIF, ExifTool, FLAC, FLIR, File, Flash, FlashPix, Font, FotoStation,
GIF, GIMP, GeoTiff, H264, HTML, ICC_Profile, ID3, IPTC, ITC, JFIF, JPEG,
Jpeg2000, LNK, Leaf, Lytro, M2TS, MIE, MIFF, MNG, MOI, MPC, MPEG, MPF, MXF,
MakerNotes, Matroska, Meta, Ogg, OpenEXR, PDF, PICT, PLIST, PNG, PSP, Palm,
PanasonicRaw, PhotoCD, PhotoMechanic, Photoshop, PostScript, PrintIM,
QuickTime, RAF, RIFF, RSRC, RTF, Radiance, Rawzor, Real, SVG, SigmaRaw,
Stim, Theora, Torrent, VCard, Vorbis, XML, XMP, ZIP
|
| 1 (Specific Location) |
AC3, AFCP, AIFF, APE, ASF, AVI1, Adobe, AdobeCM, AdobeDNG, Apple, Audible,
CIFF, Canon, CanonCustom, CanonRaw, CanonVRD, Casio, Chapter#, Composite,
DICOM, DNG, DV, DjVu, DjVu-Meta, Ducky, EPPIM, EXE, EXIF, ExifIFD, ExifTool,
FLAC, FLIR, File, Flash, FlashPix, Font, FotoStation, FujiFilm, FujiIFD, GE,
GIF, GIMP, GPS, GeoTiff, GlobParamIFD, GraphConv, H264, HP, HTC, HTML,
HTML-dc, HTML-ncc, HTML-office, HTML-prod, HTML-vw96, HTTP-equiv, ICC-chrm,
ICC-clrt, ICC-header, ICC-meas, ICC-meta, ICC-view, ICC_Profile,
ICC_Profile#, ID3, ID3v1, ID3v1_Enh, ID3v2_2, ID3v2_3, ID3v2_4, IFD0, IFD1,
IPTC, IPTC#, ITC, InteropIFD, JFIF, JPEG, JPEG-HDR, JVC, Jpeg2000, KDC_IFD,
Kodak, KodakBordersIFD, KodakEffectsIFD, KodakIFD, KyoceraRaw, LNK, Leaf,
LeafSubIFD, Leica, Lytro, M2TS, MAC, MIE-Audio, MIE-Camera, MIE-Canon,
MIE-Doc, MIE-Extender, MIE-Flash, MIE-GPS, MIE-Geo, MIE-Image, MIE-Lens,
MIE-Main, MIE-MakerNotes, MIE-Meta, MIE-Orient, MIE-Preview, MIE-Thumbnail,
MIE-UTM, MIE-Unknown, MIE-Video, MIFF, MNG, MOBI, MOI, MPC, MPEG, MPF0,
MPImage, MXF, MakerNotes, MakerUnknown, Matroska, MediaJukebox, MetaIFD,
Microsoft, Minolta, MinoltaRaw, Motorola, NITF, Nikon, NikonCapture,
NikonCustom, NikonScan, Nintendo, Ocad, Ogg, Olympus, OpenEXR, PDF, PICT,
PNG, PNG-pHYs, PSP, Palm, Panasonic, PanasonicRaw, Pentax, PhaseOne,
PhotoCD, PhotoMechanic, Photoshop, PictureInfo, PostScript, PreviewIFD,
PrintIM, ProfileIFD, Qualcomm, QuickTime, RAF, RAF2, RIFF, RMETA, RSRC, RTF,
Radiance, Rawzor, Real, Real-CONT, Real-MDPR, Real-PROP, Real-RA3, Real-RA4,
Real-RA5, Real-RJMD, Reconyx, Ricoh, SPIFF, SR2, SR2DataIFD, SR2SubIFD,
SRF#, SVG, Samsung, Sanyo, Scalado, Sigma, SigmaRaw, Sony, SonyIDC, Stim,
SubIFD, System, Theora, Torrent, Track#, VCalendar, VCard, Version0, Vorbis,
XML, XMP, XMP-DICOM, XMP-GPano, XMP-MP, XMP-MP1, XMP-PixelLive, XMP-aas,
XMP-acdsee, XMP-album, XMP-apple-fi, XMP-aux, XMP-cc, XMP-cell, XMP-crs,
XMP-dc, XMP-dex, XMP-digiKam, XMP-dwc, XMP-exif, XMP-exifEX,
XMP-expressionmedia, XMP-extensis, XMP-fpv, XMP-getty, XMP-ics,
XMP-iptcCore, XMP-iptcExt, XMP-lr, XMP-mediapro, XMP-microsoft,
XMP-mwg-coll, XMP-mwg-kw, XMP-mwg-rs, XMP-pdf, XMP-pdfx, XMP-photomech,
XMP-photoshop, XMP-plus, XMP-prism, XMP-prl, XMP-pur, XMP-rdf, XMP-swf,
XMP-tiff, XMP-x, XMP-xmp, XMP-xmpBJ, XMP-xmpDM, XMP-xmpMM, XMP-xmpNote,
XMP-xmpPLUS, XMP-xmpRights, XMP-xmpTPg, ZIP
|
| 2 (Category) |
Audio, Author, Camera, Document, ExifTool, Image, Location, Other,
Preview, Printing, Time, Unknown, Video
|
| 3 (Document Number) |
Doc#, Main
|
| 4 (Instance Number) |
Copy#
|
Example:
@groupList = Image::ExifTool::GetAllGroups($family);
|
Get list of all deletable group names.
| Prototype | GetDelGroups() |
| Inputs |
None
|
| Returns | A list of deletable group names in
alphabetical order.
|
Below is a current list of deletable group names. All names in this list
are either family 0 or family 1 group names, with the exception of
'Trailer' which allows all trailers in JPEG and TIFF-format images
to be deleted at once, including unknown trailers. To schedule a group for
deletion, call SetNewValue with an undefined value
and a tag name like 'Trailer:*'.
AFCP, APP0, APP1, APP10, APP11, APP12, APP13, APP14, APP15, APP2, APP3,
APP4, APP5, APP6, APP7, APP8, APP9, Adobe, Audio, Author, CIFF, Camera,
CanonVRD, Copyright, Document, Ducky, EXIF, ExifIFD, ExifTool, File,
FlashPix, FotoStation, GPS, GlobParamIFD, ICC_Profile, IFD0, IFD1, IPTC,
Image, InteropIFD, JFIF, Jpeg2000, Location, MIE, MPF, MakerNotes, Meta,
MetaIFD, NikonCapture, Other, PDF, PDF-update, PNG, PNG-pHYs, PhotoMechanic,
Photoshop, PrintIM, Printing, RMETA, RSRC, SubIFD, Time, Trailer, Video,
XML, XML-*, XMP, XMP-*
Note that the JPEG "APP" groups are special, and are used only to delete
application segments which are not associated with another deletable group. For
example, deleting 'APP14:*' will delete other APP14 segments, but
not the APP14 "Adobe" segment. Also note that deleting a family 0 or 1 group
will delete the entire corresponding block of metadata, but deleting a family 2
group (eg. Audio, Author, Camera, etc.) deletes the individual tags belonging
to that category.
Example:
my @delGroups = Image::ExifTool::GetDelGroups();
|
Get type of file given file name.
| Prototype | GetFileType(;$$) |
| Inputs |
0) [optional] File name or extension
1) [optional] Flag to return a description instead of a type.
Set to 0 to return type for recognized but unsupported files (otherwise the
return value for unsupported files is undef).
|
| Returns | A string, based on the file extension, which
indicates the basic format of the file. Note that some files may be based on
other formats (like many RAW image formats are based on TIFF). In array
context, may return more than one file type if the file may be based on
different formats. Returns undef if files with this extension are not yet
supported by ExifTool. Returns a list of extensions for all supported file
types if no input extension is specified (or all recognized file types if the
description flag is set to 0). Returns a more detailed description of the
specific file format when the description flag is set. |
Examples:
my $type = Image::ExifTool::GetFileType($filename);
my $desc = Image::ExifTool::GetFileType($filename, 1);
|
Can the specified file be written?
| Prototype | CanWrite($) |
| Inputs |
0) File name or extension |
| Returns | True if ExifTool supports writing files of
this type (based on the file extension). |
Example:
my $writable = Image::ExifTool::CanWrite($filename);
|
Can the specified file be created?
| Prototype | CanCreate($) |
| Inputs |
0) File name or extension |
| Returns | True if ExifTool can create files with this
extension from scratch.
Currently, this can only be done with XMP, MIE, ICC,
VRD, DR4, EXV and EXIF files. |
Example:
my $creatable = Image::ExifTool::CanCreate($filename);
|
Add user-defined tags to an existing tag table at run time. This differs from
the usual technique of creating user-defined tags via the
%Image::ExifTool::UserDefined hash (see the
sample config file), because it allows tags to be added
after the tag table has been initialized.
| Prototype | AddUserDefinedTags($%) |
| Inputs | 0) Destination tag table name
1-N) Pairs of tag ID / tag information hash references for the new tags
|
| Returns | The number of tags added |
Example:
use Image::ExifTool ':Public';
my %tags = (
TestTagID1 => { Name => 'TestTagName1' },
TestTagID2 => { Name => 'TestTagName2' },
);
my $num = AddUserDefinedTags('Image::ExifTool::PDF::Info', %tags);
|
Notes:
Pre-existing tags with the same ID will be replaced in the destination table.
See lib/Image/ExifTool/README in the full distribution for full details on the
elements of the tag information hash.
<-- Back to ExifTool home page